PKGBUILD

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=plasma-nm
pkgver=5.27.80.20231020
_dirver=$(echo $pkgver | cut -d. -f1-3)
pkgrel=1
pkgdesc='Plasma applet written in QML for managing network connections'
arch=(x86_64)
url='https://kde.org/plasma-desktop/'
license=(GPL2)
depends=(gcc-libs
         glib2
         glibc
         kcmutils
         kcolorscheme
         kcompletion
         kconfig
         kcoreaddons
         kdbusaddons
         ki18n
         kio
         knotifications
         kwallet
         kwidgetsaddons
         kwindowsystem
         libnm
         modemmanager-qt
         networkmanager-qt
         plasma-workspace
         qca-qt6
         qcoro-qt6
         qt6-base
         qt6-declarative
         solid)
makedepends=(extra-cmake-modules
             openconnect)
optdepends=('openconnect: Cisco AnyConnect VPN plugin'
            'qt6-webengine: Cisco AnyConnect VPN plugin')
groups=(plasma)
#source=(https://download.kde.org/stable/plasma/$_dirver/$pkgname-$pkgver.tar.xz{,.sig})
makedepends+=(git)
_commit=b28291959bf3129ea8ee8cf8c865a99803cb1fef
source=(git+https://invent.kde.org/plasma/$pkgname#commit=$_commit)
sha256sums=('SKIP')
validpgpkeys=('E0A3EB202F8E57528E13E72FD7574483BB57B18D'  # Jonathan Esk-Riddell <jr@jriddell.org>
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

build() {
  cmake -B build -S $pkgname \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}