upgpkg: 2020.5.24-1

PKGBUILD

+# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
+
+_pkgname=nox
+pkgname=python-$_pkgname
+pkgver=2020.5.24
+pkgrel=1
+pkgdesc='Flexible test automation for Python'
+arch=('any')
+url='https://github.com/theacodes/nox'
+license=('Apache')
+depends=('python' 'python-argcomplete' 'python-colorlog' 'python-py' 'python-virtualenv')
+optdepends=('python-jinja: tox_to_nox'
+            'python-tox: tox_to_nox')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest-runner' 'python-jinja' 'python-tox')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha512sums=('6148ef30ef7ab787f7eaf3a4fc35504df351d51b22a1eed42899356ba695f4ca88b3d3a5880d421973307c00a8c1d3fb02fb9b81f2d32e78e2de0062223a8bfe')
+
+prepare() {
+  # missing python-contexter
+  rm $_pkgname-$pkgver/tests/test_main.py
+}
+
+build() {
+  cd $_pkgname-$pkgver
+
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  python setup.py pytest
+}
+
+package() {
+  cd $_pkgname-$pkgver
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et: