Add Gradle build script for the custom REST endpoint

roles/keycloak/files/providers/keycloak-mailpass-rest/build.gradle.kts

+plugins {
+    java
+}
+
+java {
+    toolchain {
+        languageVersion.set(JavaLanguageVersion.of(11))
+    }
+}
+
+group = "org.archlinux"
+version = "1.0.0"
+
+repositories {
+    mavenCentral()
+}
+
+dependencies {
+    val keycloakVersion = "11.0.3"
+    val javaxVersion = "2.0.1.Final"
+    val bouncyCastleVersion = "1.67"
+
+    implementation("org.bouncycastle:bcprov-jdk15on:$bouncyCastleVersion")
+
+    compileOnly("org.keycloak:keycloak-core:$keycloakVersion")
+    compileOnly("org.keycloak:keycloak-server-spi:$keycloakVersion")
+    compileOnly("org.keycloak:keycloak-server-spi-private:$keycloakVersion")
+    compileOnly("org.jboss.spec.javax.ws.rs:jboss-jaxrs-api_2.1_spec:$javaxVersion")
+}
+
+tasks {
+    jar {
+        from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) }) {
+            exclude("META-INF/MANIFEST.MF")
+            exclude("META-INF/*.SF")
+            exclude("META-INF/*.DSA")
+            exclude("META-INF/*.RSA")
+        }
+    }
+
+    wrapper {
+        gradleVersion = "6.7"
+    }
+}